Este módulo será el encargado de procesar el formulario anterior y agregar el mensaje a la base de datos.

Luego de recoger los valores del formulaio en variables, se comprueba si Nombre, email, Asunto o Mensaje están vacíos. Si lo están, se redirige al usuario a la página anterior (al formulario de la página Firmarlibro.asp) para que lo complete nuevamente. En caso contrario, se agrega el mensaje a la base de datos y se envía al usuario a la página principal del libro (default.asp).

Addmensaje.asp

<%
Const adOpenForwardOnly = 0
Const adOpenKeyset = 1
Const adOpenDynamic = 2
Const adOpenStatic = 3
Const adLockReadOnly = 1
Const adLockPessimistic = 2
Const adLockOptimistic = 3
Const adLockBatchOptimistic = 4

Nombre = request.form("Nombre")
Pais = request.form("Pais")
email = request.form("email")
url = request.form("url")
Asunto = request.form("Asunto")
Mensaje = replace(request.form("Mensaje"),chr(10),"<br>")

'en caso que el campo url tenga como único valor el valor por defecto
'se convierte a valor nulo
if url="http://" then
url = ""
end if

if Nombre="" or email="" or Asunto="" or Mensaje="" then
response.redirect "firmarlibro.asp?Mensaje=2"

else
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open("DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & server.MapPath("libvis.mdb"))
set rs=createobject("ADODB.Recordset")
rs.CursorType = adOpenKeyset
rs.LockType = adLockOptimistic

rs.open "mensajes",conn
rs.addnew

rs("Nombre")=Nombre
rs("email")=email
rs("Pais")=Pais
rs("url")=url
rs("Asunto")=Asunto
rs("Mensaje")=Mensaje
rs("Fecha")=Date()
rs.update
rs.close

response.redirect "Default.asp"
end if
%>
<!-- esta línea solo sirve para casos en los que la navegación del usuario
sea muy lenta, no se les muestre una página en blanco.
No es necesaria y puede quitarse sin problemas -->
<br><br><br>
<p align="center"><font face="Arial" color="Blue">Procesando formulario. Por favor, espere...</p>